% Some TeX abbreviations for conveniance
verbatimtex
\def\e#1{\sqrt[5]2 \cdot e^{\pi i/15 #1}}
\def\en#1{\e{+2\pi i{#1}/5}}
etex

% Unit length for drawings (not for TeX)
u := 25mm;

% Radius of Circle
r := 2**(1/5);

ru := 2*r*u;

% Bounding Box
z.min = (-2.3,-1.5)*u;
z.max = (2.2,2.1)*u;

pair s;

% Draw Background to ensure good Contrast
fill for s = z.min, (x.max,y.min), z.max, (x.min,y.max):
   s-- endfor cycle withcolor (.99,.99,.99);

path p;

% Draw Circle
p := fullcircle scaled ru;

draw p;

% Real Axis
drawarrow (-2.1,0)*u--(2,0)*u;
label.ulft(btex $\Re\mathrm e$ etex, (2,0)*u);

% Imag Axis
drawarrow (0,-1.4)*u--(0,2)*u;
label.llft(btex $\Im\mathrm m$ etex, (0,2)*u);

% Draw the 5th Roots as Arrows with Labels
for i=0 upto 4:
   pair q;
   q := point 8*(1/30+i/5) of p;
   drawarrow (0,0)--q;
   if i=0:
      label.rt(btex $\e{}$ etex, q);
   elseif i=1:
      label.urt(btex $\en{}$ etex, q);
   elseif i=2:
      label.lft(btex $\en{\cdot 2}$ etex, q);
   elseif i=3:
      label.llft(btex $\en{\cdot 3}$ etex, q);
   else:
      label.lrt(btex $\en{\cdot 4}$ etex, q);
   fi;
endfor;

% Original Number we took the 5th Roots of
s := (1,sqrt(3))*u;
drawarrow (0,0)--s;
label.rt(btex $1+i\sqrt3=2\cdot e^{\pi i/3}$ etex, s);

% Indicate "1"
s := (u,0);
d := 0.03u;
draw ((0,-d)--(0,d)) shifted s withcolor black;
label.llft(btex $1$ etex, s);

% Indicate Circle's Radius
draw ((0,0)--(d,-d)) shifted (r*u,0) withcolor black;
label.lrt(btex $\sqrt[5]2$ etex, (r,0)*u);